home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 008 / pspic3.arc / CPNOM.LIB next >
Encoding:
Text File  |  1986-09-04  |  2.1 KB  |  68 lines
  1. * Library of Comparator subcircuit definitions
  2. *
  3. * This is a reduced version of MicroSim's voltage comparator subcircuit
  4. *   library.  You are welcome to make as many copies of it as you find
  5. *   convenient.
  6. *
  7. * Release date: 86/01/04
  8. *
  9. * The parameters in this opamp library were derived from the data
  10. * sheets for each part.  The comparator macro model used is derived
  11. * from the op amp macro model used in the OPNOM.LIB file.  The op amp
  12. * macro model is described in:
  13. *
  14. *    Macromodeling of Integrated Circuit Operational Amplifiers
  15. *        by Graeme Boyle, Barry Cohn, Donald Pederson, and
  16. *           James Solomon
  17. *    IEEE Journal of Solid-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  18. *
  19. * The comparators are modelled at room temperature.  The macro model
  20. * does not track changes with temperature.  This library file contains
  21. * models for nominal, not worst case, devices.
  22. *
  23. * Although we do not use it, a slightly more elaborate comparator macro
  24. * model is described in:
  25. *
  26. *    An Integrated-Circuit Comparator Macromodel
  27. *        by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch
  28. *    IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976
  29. *
  30. * Note: Each macromodel consists of a subcircuit definition AND a set
  31. *    of .MODEL statements.  The .MODEL statements should be put into
  32. *    the main circuit file along with the subcircuit definition.
  33. *
  34. *
  35. * LM111
  36. *
  37. .SUBCKT LM111    1   2   3   4   7
  38. *               Vi+ Vi- gnd Vp+ Vout
  39. Q1 11 1 13 LM111QA
  40. Q2 12 2 14 LM111QB
  41. RE1 13 10 2.240157D+03
  42. RE2 14 10 2.240157D+03
  43. RC1 3 11 2.500000D+03
  44. RC2 3 12 2.500000D+03
  45. IEE 4 10 2.001200D-04
  46. RE 10 4 9.994004D+05
  47. GCM 3 21 10 3 4.000000D-08
  48. GA 21 3 11 12 4.000000D-04
  49. R2 21 3 1.000000D+05
  50. C2 0 22 2.742857D-08
  51. GB 22 3 21 3 1.600000D+00
  52. RO2 22 3 1.000000D+02
  53. RO1 22 6 5.000000D+01
  54. D3 22 25 LM111DA
  55. D4 25 22 LM111DA
  56. VE 25 3 7.139894D-01
  57. R3 6 26 1.600000D+02
  58. C3 26 3 5.625000D-10
  59. Q3 7 26 3 LM111QC
  60. .ENDS
  61. .MODEL LM111DA D (IS=8.000000D-16)
  62. .MODEL LM111QA PNP (IS=8.000000D-16 BF=1.612903D+03)
  63. .MODEL LM111QB PNP (IS=8.154739D-16 BF=1.724138D+03)
  64. .MODEL LM111QC NPN (IS=10E-15 BF=1.000000D+01
  65. +  RC=60 TF=6.000000D-08)
  66. *
  67. * End of library file
  68.